define "Follow-up Diagnostic Mammogram":
  [Observation: "Diagnostic Mammography"] MammogramDiagnostic
    where MammogramDiagnostic.status in { 'final', 'amended', 'corrected' }
      and MammogramDiagnostic.value as Concept in "BI_RADS Categories 1, 2, and 3"
      and MammogramDiagnostic.effective during day of Interval[start of "Measurement Period", end of "Measurement Period" + 60 days]

define "Mammogram Screening with Abnormal Result":
  [Observation: "Screening Mammogram (Grouping)"] MammogramScreening
    where MammogramScreening.status in { 'final', 'amended', 'corrected' }
      and MammogramScreening.value as Concept in "BI_RADS Categories 0, 4, and 5"
      and MammogramScreening.effective during day of "Measurement Period"

define "Index Abnormal Screening Mammogram":
  First("Mammogram Screening with Abnormal Result" AbnormalMammogram
      sort by effective
  )

define "Follow-up MRI of the Breast":
  [Observation: "MRI of the Breast"] mri
    where mri.status in { 'final', 'amended', 'corrected' }
      and mri.value as Concept in "BI_RADS Categories 1, 2, and 3"
      and mri.effective during day of Interval[start of "Measurement Period", end of "Measurement Period" + 60 days]

define "Follow-up Ultrasound of the Breast":
  [Observation: "Ultrasound of the Breast"] ultrasound
    where ultrasound.status in { 'final', 'amended', 'corrected' }
      and ultrasound.value as Concept in "BI_RADS Categories 1, 2, and 3"
      and ultrasound.effective during day of Interval[start of "Measurement Period", end of "Measurement Period" + 60 days]

define "Has Follow-up Supplementary Imaging Within 60 Days Of Index Abnormal Screening Mammogram":
  exists ( "Follow-up Diagnostic Mammogram" FollowupMammogram
      where FollowupMammogram.effective during day of Interval["Index Abnormal Screening Mammogram".effective, "Index Abnormal Screening Mammogram".effective + 60 days]
  )
    or exists ( "Follow-up MRI of the Breast" FollowupMri
        where FollowupMri.effective during day of Interval["Index Abnormal Screening Mammogram".effective, "Index Abnormal Screening Mammogram".effective + 60 days]
    )
    or exists ( "Follow-up Ultrasound of the Breast" FollowupUltrasound
        where FollowupUltrasound.effective during day of Interval["Index Abnormal Screening Mammogram".effective, "Index Abnormal Screening Mammogram".effective + 60 days]
    )

define "Follow-up Breast Biopsy Procedure":
  [Procedure: "Breast Cancer Biopsy and Surgical Excision"] BreastBiopsyPerformed
    where BreastBiopsyPerformed.status = 'completed'
      and BreastBiopsyPerformed.performed starts during day of Interval[start of "Measurement Period", end of "Measurement Period" + 60 days]

define "Has Follow-up Breast Biopsy Procedure Within 60 Days of The Index Abnormal Screening Mammogram":
  exists ( "Follow-up Breast Biopsy Procedure" BreastBiopsyPerformed
      where BreastBiopsyPerformed.performed starts 60 days or less on or after "Index Abnormal Screening Mammogram".effective
  )

define "Numerator":
  "Has Follow-up Supplementary Imaging Within 60 Days Of Index Abnormal Screening Mammogram"
    or "Has Follow-up Breast Biopsy Procedure Within 60 Days of The Index Abnormal Screening Mammogram"

define "Initial Population":
  AgeInYearsAt("Index Abnormal Screening Mammogram".effective) in Interval[40, 75]
    and Patient.gender = 'female'
    and exists "Mammogram Screening with Abnormal Result"

define "Denominator":
  "Initial Population"